#!/usr/bin/perl 
#------------------------------------------------------------------------------
# $Id: hdiff,v 1.1 2000/03/26 19:52:21 peters Exp peters $
#
# NAME:		hdiff
#
# PURPOSE:	HTML diff. Produces a colourised HTML diff output which is 
#		much easier to read than standard diff output.
#
# SOURCE:	www.ginini.com/software/hdiff
# 
# 		hdiff is derived from cvs2html from www.sslug.dk/cvs2html
#------------------------------------------------------------------------------

require 5.000;

use Getopt::Std;

$diff='/usr/bin/diff';

#
# Colors and font to show the diff type of code changes
#
$diffcolorHeading='#99BBBB';	# color of 'Line'-heading of each diffed file
$diffcolorEmpty='#CCCCCC';	# color of 'empty' lines
$diffcolorAdd='#FF9999';	# Removed line(s) (left)  (  -  )
$diffcolorChange='#99FF99';	# Changed line(s) (     both    )
$diffcolorRemove='#CCCCFF';	# Added line(s)   (  - )  (right)
$diffcolorDarkChange ='#99CC99';# lines, which are empty in change
$difffontface="Helvetica,Arial";
$difffontsize="-1";

#-----------------------------------------------------------------------------
# END OF CONFIGURABLE OPTIONS
#-----------------------------------------------------------------------------

# MAIN BODY
#
# Process options
#
getopts('h:f');

die "Usage: $0 [-f <footer>] [-h <header>] [file1] [file2]\n" if (scalar @ARGV != 2);
$File1=$ARGV[0];
$File2=$ARGV[1];

die "$File1 not found\n" if (! -f $File1);
die "$File2 not found\n" if (! -f $File2);

HtmlHeader();

human_readable_diff("$Title",$File1,$File2);

HtmlFooter();

#--------------------------------------------------------------------------
sub htmlify {
	local($string, $pr) = @_;

	# Special Characters; RFC 1866
	$string =~ s/&/&amp;/g;
	$string =~ s/\"/&quot;/g; 
	$string =~ s/</&lt;/g;
	$string =~ s/>/&gt;/g;

	# get URL's as link ..
	$string =~ s§(http|ftp)(://[-a-zA-Z0-9%.~:/]+)([?&]([-a-zA-Z0-9%.~:_]+)=([-a-zA-Z0-9%.~:_])+)*§<A HREF="$1$2$3">$1$2$3</A>§;
	# get e-mails as link
	$string =~ s§([-a-zA-Z0-9.]+@([-a-zA-Z0-9]+\.)+[A-Za-z]{2,4})§<A HREF="mailto:$1">$1</A>§;

	# get #PR as link ..
	if ($pr && defined $prcgi) {
	    $string =~ s!\b((pr[:#]?\s*#?)|((bin|conf|docs|gnu|i386|kern|misc|ports)\/))(\d+)\b!<A HREF="$prcgi?pr=$5">$&</A>!ig;
	}

	return $string;
}

sub spacedHtmlText {
	my($string, $pr) = @_;

	# Cut trailing spaces
	s/\s+$//;

	# Expand tabs
	$string =~ s/\t+/' ' x (length($&) * $tabstop - length($`) % $tabstop)/e
	    if (defined $tabstop);

	# replace <tab> and <space> (§ is to protect us from htmlify)
	# gzip can make excellent use of this repeating pattern :-)
	$string =~ s/§/§%/g; #protect our & substitute
	if ($hr_breakable) {
	    # make every other space 'breakable'
	    $string =~ s/	/ §nbsp; §nbsp; §nbsp; §nbsp;/g;    # <tab>
	    $string =~ s/  / §nbsp;/g;                              # 2 * <space>
	    # leave single space as it is
	}
	else {
	    $string =~ s/	/§nbsp;§nbsp;§nbsp;§nbsp;§nbsp;§nbsp;§nbsp;§nbsp;/g; 
	    $string =~ s/ /§nbsp;/g;
	}

	$string = htmlify($string);

	# unescape
	$string =~ s/§([^%])/&$1/g;
	$string =~ s/§%/§/g;

	return $string;
}

sub flush_diff_rows ($$$$)
{
    local $j;
    my ($leftColRef,$rightColRef,$leftRow,$rightRow) = @_;
    if ($state eq "PreChangeRemove") {          # we just got remove-lines before
      for ($j = 0 ; $j < $leftRow; $j++) {
          print  "<tr><td bgcolor=\"$diffcolorRemove\">@$leftColRef[$j]</td>";
          print  "<td bgcolor=\"$diffcolorEmpty\">&nbsp;</td></tr>\n";
      }
    }
    elsif ($state eq "PreChange") {             # state eq "PreChange"
      # we got removes with subsequent adds
      for ($j = 0; $j < $leftRow || $j < $rightRow ; $j++) {  # dump out both cols
          print  "<tr>";
          if ($j < $leftRow) { print  "<td bgcolor=\"$diffcolorChange\">@$leftColRef[$j]</td>"; }
          else { print  "<td bgcolor=\"$diffcolorDarkChange\">&nbsp;</td>"; }
          if ($j < $rightRow) { print  "<td bgcolor=\"$diffcolorChange\">@$rightColRef[$j]</td>"; }
          else { print  "<td bgcolor=\"$diffcolorDarkChange\">&nbsp;</td>"; }
          print  "</tr>\n";
      }
    }
}

sub HtmlHeader {
  if ($opt_h) {
      open(HEADER,"$opt_h") or die "Can not open $opt_h $!\n";
      print <HEADER>;
      close(HEADER);
  }
  else {
      print "<HTML>\n<HEAD>\n";
      print "<TITLE>hdiff Output</TITLE></HEAD>\n";
      print  "<BODY BGCOLOR=\"#EEEEEE\">\n";
      print "<CENTER><H1>hdiff output</H1></CENTER>\n";
  }

  print "<table width=\"100%\" border=0 cellspacing=0 cellpadding=1 bgcolor=\"$navigationHeaderColor\">";
  print "<tr valign=bottom><td>";
  print "</tr></table>";
}

sub HtmlFooter {
  print  "</table>";
  print "<table border=0>";
  print "<tr><td>";
  print "\n<table border=1><tr><td align=center>";
  print  "<font size=+1>Legend</font><br><table border=0 cellspacing=0 cellpadding=1>\n";
  print  "<tr><td align=center bgcolor=\"$diffcolorRemove\">Lines Added</td><td bgcolor=\"$diffcolorEmpty\">&nbsp;</td></tr>";
  print  "<tr bgcolor=\"$diffcolorChange\"><td align=center colspan=2>Lines changed</td></tr>";
  print  "<tr><td bgcolor=\"$diffcolorEmpty\">&nbsp;</td><td align=center bgcolor=\"$diffcolorAdd\">Lines Removed</td></tr>";
  print  "</table></td></tr></table>\n";

  if ($opt_f) {
      open(FOOTER,"$opt_f") or die "Can not open $opt_f $!\n";
      print <FOOTER>;
      close(FOOTER);
      return;
  }
  else {
      print "</BODY></HTML>\n";
  }
}

##
# Function to generate Human readable diff-files
# human_readable_diff(String revision_to_return_to);
##
sub human_readable_diff(){
  my($title,$file1,$file2) = @_;

  local ($i,$difftxt, $where_nd, $filename, $pathname);

  open(DIFF,"$diff -u $file1 $file2 |") || die;
  ($where_nd = $where) =~ s/.diff$//;
  ($filename = $where_nd) =~ s/^.*\///;
  ($pathname = $where_nd) =~ s/(Attic\/)?[^\/]*$//;
  ($scriptwhere_nd = $scriptwhere) =~ s/.diff$//;

  print "\n\n<center><font size=+2 face=Arial>$title</font></center><p>\n";
  print "<table border=0 cellspacing=0 cellpadding=0 width=100%>\n";
  print "<tr bgcolor=#ffffff>\n";
  print "<th width=\"50%\" valign=TOP>";
  print "$ARGV[0]";
  print "</th>\n";
  print "<th width=\"50%\" valign=TOP>";
  print "$ARGV[1]";
  print "</th>\n";

  $fs="<font face=\"$difffontface\" size=\"$difffontsize\">";
  $fe="</font>";

  $leftRow = 0;
  $rightRow = 0;

  #
  # Process diff text
  #
  while (<DIFF>) {
      $difftxt = $_;
      
      if ($difftxt =~ /^@@/) {
	  ($oldline,$newline,$funname) = $difftxt =~ /@@ \-([0-9]+).*\+([0-9]+).*@@(.*)/;
	  $state = "dump";
	  $leftRow = 0;
	  $rightRow = 0;
      }
      else {
	  ($diffcode,$rest) = $difftxt =~ /^([-+ ])(.*)/;
	  $_= spacedHtmlText ($rest);
	  
	  # Add fontface, size
	  $_ = "$fs&nbsp;$_$fe";
	  
	  #########
	  # little state machine to parse unified-diff output (Hen, zeller@think.de)
	  # in order to get some nice 'ediff'-mode output
	  # states:
	  #  "dump"             - just dump the value
	  #  "PreChangeRemove"  - we began with '-' .. so this could be the start of a 'change' area or just remove
	  #  "PreChange"        - okey, we got several '-' lines and moved to '+' lines -> this is a change block
	  ##########

	  if ($diffcode eq '+') {
	      if ($state eq "dump") {  # 'change' never begins with '+': just dump out value
		  print  "<tr><td bgcolor=\"$diffcolorEmpty\">&nbsp;</td><td bgcolor=\"$diffcolorAdd\">$_</td></tr>\n";
	      }
	      else {                   # we got minus before
		  $state = "PreChange";
		  $rightCol[$rightRow++] = $_;
	      }
	  } 
	  elsif ($diffcode eq '-') {
	      $state = "PreChangeRemove";
	      $leftCol[$leftRow++] = $_;
        }
        else {  # empty diffcode
            flush_diff_rows \@leftCol, \@rightCol, $leftRow, $rightRow;
	      print  "<tr><td>$_</td><td>$_</td></tr>\n";
	      $state = "dump";
	      $leftRow = 0;
	      $rightRow = 0;
	  }
      }
  }
  flush_diff_rows \@leftCol, \@rightCol, $leftRow, $rightRow;

  # state is empty if we didn't have any change
  if (!$state) {
      print "<tr><td colspan=2>&nbsp;</td></tr>";
      print "<tr bgcolor=\"$diffcolorEmpty\" >";
      print "<td colspan=2 align=center><b>- No viewable Change -</b></td></tr>";
  }
  close(DIFF);

  print "</table>\n\n";
  print "<br><hr noshade width=100%>\n";

}